编辑 XML

阅读718

更新时间2025-07-30

在服务器端

打开、编辑并保存 XML

现在，我们会为您展示如何打开、编辑及保存存储于服务器上的 XML 文件。

我们将使用 XSL 把 XML 文档转换到一个 HTML 表单中。XML 元素的值会被写到 HTML 表单中的 HTML 输入域。此表单是可编辑的。在被编辑完成后，数据会被提交回服务器，XML 文件会得到更新（这部分由 ASP 完成）。

XML 文件和 XSL 文件

首先，请看将被使用的 XML 文档 ("tool.xml")：



  
    HAMMER HG2606 
  
  
    32456240 
  
  
    $30.00

查看 XML 文件。

接着，请看下面的样式表("tool.xsl")：








Tool Information (edit):

查看 XSL 文件。

上面这个 XSL 文件会循环遍历 XML 文件中的元素，并为每个 XML "field" 元素创建一个输入域。field 元素的 id 属性的值被添加到每个 HTML 输入域的 id 和 name 属性。"value" 元素的值被添加到每个 HTML 输入域的 "value" 属性。结果是，可以得到一个包含 XML 文件中值的可编辑的 HTML 表单。

然后，我们还有第二个样式表："tool_updated.xsl"。这个 XSL 文件会被用来显示已更新的 XML 数据。这个样式表不会输出可编辑 HTML 表单，而是一个静态的 HTML 表格：







Updated Tool Information:

查看 XSL 文件。

ASP 文件

在上面 "tool.xsl" 文件中， HTML 表单的 action 属性的值是 "edittool.asp" 。

"edittool.asp" 页面包含两个函数：loadFile() 载入并转换 XML 文件，updateFile() 函数更新 XML 文件：

<%
function loadFile(xmlfile,xslfile)
Dim xmlDoc,xslDoc

'加载 XML 文件
set xmlDoc = Server.CreateObject("Microsoft.XMLDOM")
xmlDoc.async = false
xmlDoc.load(xmlfile)

'加载 XSL 文件
set xslDoc = Server.CreateObject("Microsoft.XMLDOM")
xslDoc.async = false
xslDoc.load(xslfile)

'转换文件
Response.Write(xmlDoc.transformNode(xslDoc))
end function

function updateFile(xmlfile)
Dim xmlDoc,rootEl,f
Dim i

'加载 XML 文件
set xmlDoc = Server.CreateObject("Microsoft.XMLDOM")
xmlDoc.async = false
xmlDoc.load(xmlfile)

'设置 rootEl 变量为根元素
Set rootEl = xmlDoc.documentElement

'循环遍历 form 集
for i = 1 To Request.Form.Count
   '除去表单中的按钮元素
   if instr(1,Request.Form.Key(i),"btn_")=0 then
   'selectSingleNode 方法可查询匹配某个查询的 XML 文件中的某个单一节点。
   '此查询会请求 value 元素，此 value 元素是 field 元素的子元素，
   '而此 field 元素拥有可匹配表单集中当前 key 值的 id 属性。
   '如果存在匹配，则设置 text 属性为表单集中当前域的值。
   set f = rootEl.selectSingleNode("field[@id='" & _
   Request.Form.Key(i) & "']/value")
   f.Text = Request.Form(i)
   end if
next

'保存已修改的 XML 文件
xmlDoc.save xmlfile

'释放所有的对象引用
set xmlDoc=nothing
set rootEl=nothing
set f=nothing

'通过一个样式表加载已修改的 XML 文件，这样客户端就可以看到所编辑的信息
loadFile xmlfile,server.MapPath("tool_updated.xsl")
end function

'如果表单已被提交，则更新XML文件并显示结果，如果没有被提交，则转换此 XML 文件以供编辑
if Request.Form("btn_sub")="" then
loadFile server.MapPath("tool.xml"),server.MapPath("tool.xsl")
else
updateFile server.MapPath("tool.xml")
end if
%>